Android Gradle必备使用技巧,未完待续,欢迎关注公众号flysnow_org,第一时间看后续技巧

每一个App都会有一个版本号,这样用户就知道自己安装的应用是哪个版本,是不是最新版,有了问题,也可以找客服报上自己的版本,让客服有针对性的帮用户解决问题。

一般的版本有三部分构成:major.minor.patch,第一个是主版本号,第二个是副版本号,第三位补丁号,这种我们常见的见识1.0.0这样的,当然也有两位的1.0,对应major.minor,这里我们以三位为例。

原始的版本信息配置方式

最开始的时候我们都是配置在build文件里的,如下:

android {
    compileSdkVersion 23
    buildToolsVersion "23.0.1"


    defaultConfig {
        applicationId "org.flysnow.app"
        minSdkVersion 14
        targetSdkVersion 23
        versionCode 1
        versionName "1.0.0"
    }
}

这种方式我们直接写在versionName的后面,比较直观。但是这种方式有个很大的问题就是修改不方便,特别当我们的build文件中有很多代码时,不容易找,而且修改容易出错,代码版本管理时也容易产生冲突。

使用Gradle模块化的机制剥离版本信息

既然最原始的方式,修改不方便,那么我们可不可以把版本号的配置单独的抽取出来的,放在单独的文件里,供build引用,就像我们在Android里,单独新建一个存放常量的Java类一样,供其他类调用,幸运的是,android是支持基于文件的模块化的,它就是apply from。

这和应用一个Gradle是一样的,我们不光可以应用一个插件,也可以把另一个gradle文件引用进来。我们新建一个version.gradle文件,用于专门存放我们的版本。

version.gradle

ext {
    appVersionCode =1
    appVersionName = "1.0.0"
}

ext{}块表明我们要为当前project创建扩展属性,以供其他脚本引用,他就像我们java里的变量一样。创建好之后,我们在build.gradle中引用它。

build.gradle

apply from: 'version.gradle'
android {
    compileSdkVersion 23
    buildToolsVersion "23.0.1"


    defaultConfig {
        applicationId "org.flysnow.app"
        minSdkVersion 14
        targetSdkVersion 23
        versionCode appVersionCode
        versionName appVersionName
    }
}

从示例中可以看到,我们先使用apply from加载我们的version.gradle脚本文件,这样它里面定义的扩展属性就可以使用了。然后我们为versionCodeversionName配置我们定义好的属性变量。

这种方式,我们每次只用修改version.gradle里的版本号就好了,方便,容易,也比较清晰,在团队协作的过程中,大家看到这个文件,就能猜测出来它大概是做什么的,而且只会负责发版的人才会修改这样文件,代码冲突少。

从git的tag中获取版本号

一般Jenkins打包发布的时候,我们都会从我们已经打好的一个tag打包发布,而tag的名字一般就是我们的版本名称,这时候我们就可以动态的获取我们的tag名称作为我们应用的名称,可能你用的不是git版本控制系统,但是大同小异,这里以git为例。

想获取当前的tag名称,在git下非常简单,使用如下命令即可,前提是你已经打了tag。

git describe --abbrev=0 --tags

知道了命令,那么我们如何在gradle中动态获取呢,这就需要gradle的exec了,gradle为我们提供了执行shell命令非常简便的方法,这就是Exec,它是一个Task任务,我们可以创建一个继承Exec的任务来执行我们的shell命令,但是比较麻烦,还好Gradle已经为我们想到了这个问题,为我们在Project对象里提供了exec方法。

ExecResult exec(Closure closure);

ExecResult exec(Action<? super ExecSpec> action);

其参数接受闭包和Action两种方式,一般我们都是采用闭包的方式,其闭包的配置是通过ExecSpec对象来配置的,我们从源代码的文档中也可以看到说明。

public interface ExecSpec extends BaseExecSpec {

    void setCommandLine(Object... args);

    void setCommandLine(Iterable<?> args);

    ExecSpec commandLine(Object... args);

    ExecSpec commandLine(Iterable<?> args);

    ExecSpec args(Object... args);

    ExecSpec args(Iterable<?> args);

    ExecSpec setArgs(Iterable<?> args);

    List<String> getArgs();
}

从ExecSpec源代码中我们可以看出,Project的exec方法的闭包可以有commandLine属性、commandLine方法、args属性以及args方法等配置供我们使用,我们这里只需要commandLine方法就可以达到目的了。

/**
 * 从git tag中获取应用的版本名称
 * @return git tag的名称
 */
def getAppVersionName(){
    def stdout = new ByteArrayOutputStream()
    exec {
        commandLine 'git','describe','--abbrev=0','--tags'
        standardOutput = stdout
    }
    return stdout.toString()
}

以上示例定义了一个getAppVersionName方法来获取我们的tag名称,exec执行后的输出可以用standardOutput获得,它是BaseExecSpec的一个属性,ExecSpec继承了BaseExecSpec,所以我们可以在exec{}闭包中使用。

通过该方法我们获取了git tag的名称后,就可以把它作为我们应用的版本名称了,使用非常简单,只用把我们的versionName配置成这个方法就好了,刚刚我们演示的时候是一个名为appVersionName的扩展属性。

android {
    compileSdkVersion 23
    buildToolsVersion "23.0.1"

    defaultConfig {
        applicationId "org.flysnow.app"
        minSdkVersion 14
        targetSdkVersion 23
        versionCode appVersionCode
        versionName getAppVersionName()
    }
}

以上我们通过git tag动态获取了版本名称,那么版本号我们如何动态获取呢?版本号作为我们内部开发的标识,主要用于控制应用进行生成,一般它是+1递增的,每一次发版,其值就+1,而每一次发版我们就会打一个tag,tag的数量也会增加1个,和我们版本号的递增逻辑是符合的,那么我们是不是可以把git tag的数量作为我们的版本号呢?答案是肯定的,这样打包发版之前,我们只需打个tag,tag数量+1,版本号也会跟着+1,达到了我们的目的。

/**
 * 以git tag的数量作为其版本号
 * @return tag的数量
 */
def getAppVersionCode(){
    def stdout = new ByteArrayOutputStream()
    exec {
        commandLine 'git','tag','--list'
        standardOutput = stdout
    }
    return stdout.toString().split("\n").size()
}

以上示例我们定义一个getAppVersionCode方法来获取git tag的数量,用于我们的版本号,然后我们在defaultConfig里使用这个方法即可,替换掉我们的appVersionCode变量。

android {
    compileSdkVersion 23
    buildToolsVersion "23.0.1"


    defaultConfig {
        applicationId "org.flysnow.app"
        minSdkVersion 14
        targetSdkVersion 23
        versionCode getAppVersionCode()
        versionName getAppVersionName()
    }
}

大功告成,这样我们在发版打包之前,只需要打一个tag,然后Android Gradle打包的时候就会自动帮我们生成应用的版本名称和版本号,非常方便,再也不用为维护应用的版本信息担心了,这也是我们使用Gradle构建的灵活之处,如果使用Ant,会麻烦的多,有兴趣的同学可以思考一下。

从属性文件中动态获取和递增版本信息

其实上一小结已经可以满足我们大部分的情况了,如果大家不想用,或者想自己更灵活的控制版本信息,可以采用Properties属性文件的方式,这里我不给出示例代码了,仅给出思路,以供参考。

大致思路如下:

  1. 在项目目录下新建一个version.properties的属性文件。
  2. 把版本名称分成三部分major.minor.patch,版本号分成一部分number,然后在version.properties中新增四个KV键值对,其key就是我们上面分好的major,minor,patch以及number,value是对应的值。
  3. 然后在build.gradle里新建两个方法,用于读取该属性文件,获取对应Key的值,然后把major.minor.patch这三个key拼接成版本名称,number用于版本号。
  4. 以上就达到了获取版本信息的目的,获取使用之后,我们还要更新我们存放在version.properties文件中的信息,这样就可以达到版本自增的目的,以供下次使用。
  5. 在更新版本名称三部分的时候,你可以自定义自己的逻辑,是逢10高位+1呢,还是其他算法,都可以自己灵活定义。
  6. 使用版本信息,更新version.properties文件的时机,记得doLast这个方法。
  7. 记得不会在自己运行调试的时候让你的版本信息自增哦,如何控制呢?就是要区分是真正的打包发版,还是平时的调试、测试,有很多办法来区分的。

动态获取生成版本信息的思路都大同小异,只是信息来源不一样,比如git tag,比如version配置等等,你自己的业务项目中还可以从其他更多的渠道来生成,这也是因为gradle的灵活,我们才可以随心所欲的做到这么多。

Android Gradle必备使用技巧,未完待续,欢迎关注公众号flysnow_org,第一时间看后续技巧。

扫码关注